3face7eddd
This changes how the templates use nixpkgs. Before, we instantiated nixpkgs in the flake and passd it directly to the configs; this was good for consistency, but silently ignored `nixpkgs.*` options, generating confusion among users. We now use modules to configure nixpkgs. This should help avoid cases such as: https://discourse.nixos.org/t/allowunfree-doesnt-work-with-flake-managed-system/21798/17 The drawback is that we can no longer test overlayed packages like so: `nix build .#foo`, you can do it like so instead: `nix build .#nixosConfigurations.your-system.pkgs.foo`. Personally, I've been avoiding override packages globally in my own config.
83 lines
2.9 KiB
Nix
83 lines
2.9 KiB
Nix
{
|
|
description = "Your new nix config";
|
|
|
|
inputs = {
|
|
# Nixpkgs
|
|
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
|
|
|
|
# Home manager
|
|
home-manager.url = "github:nix-community/home-manager";
|
|
home-manager.inputs.nixpkgs.follows = "nixpkgs";
|
|
|
|
# TODO: Add any other flake you might need
|
|
hardware.url = "github:nixos/nixos-hardware";
|
|
|
|
# Shameless plug: looking for a way to nixify your themes and make
|
|
# everything match nicely? Try nix-colors!
|
|
# nix-colors.url = "github:misterio77/nix-colors";
|
|
};
|
|
|
|
outputs = { nixpkgs, home-manager, ... }@inputs:
|
|
let
|
|
forAllSystems = nixpkgs.lib.genAttrs [
|
|
"aarch64-linux"
|
|
"i686-linux"
|
|
"x86_64-linux"
|
|
"aarch64-darwin"
|
|
"x86_64-darwin"
|
|
];
|
|
in
|
|
rec {
|
|
# Your custom packages
|
|
# Acessible through 'nix build', 'nix shell', etc
|
|
packages = forAllSystems (system:
|
|
let pkgs = nixpkgs.legacyPackages.${system};
|
|
in
|
|
import ./pkgs { inherit pkgs; }
|
|
);
|
|
# Devshell for bootstrapping
|
|
# Acessible through 'nix develop' or 'nix-shell' (legacy)
|
|
devShells = forAllSystems (system:
|
|
let pkgs = nixpkgs.legacyPackages.${system};
|
|
in
|
|
import ./shell.nix { inherit pkgs; }
|
|
);
|
|
|
|
# Your custom packages and modifications, exported as overlays
|
|
overlays = import ./overlays;
|
|
# Reusable nixos modules you might want to export
|
|
# These are usually stuff you would upstream into nixpkgs
|
|
nixosModules = import ./modules/nixos;
|
|
# Reusable home-manager modules you might want to export
|
|
# These are usually stuff you would upstream into home-manager
|
|
homeManagerModules = import ./modules/home-manager;
|
|
|
|
nixosConfigurations = {
|
|
# FIXME replace with your hostname
|
|
your-hostname = nixpkgs.lib.nixosSystem {
|
|
specialArgs = { inherit inputs; }; # Pass flake inputs to our config
|
|
modules = (builtins.attrValues nixosModules) ++ [
|
|
# > Our main nixos configuration file <
|
|
./nixos/configuration.nix
|
|
# Our common nixpkgs config (unfree, overlays, etc)
|
|
(import ./nixpkgs-config.nix { inherit overlays; })
|
|
];
|
|
};
|
|
};
|
|
|
|
homeConfigurations = {
|
|
# FIXME replace with your username@hostname
|
|
"your-username@your-hostname" = home-manager.lib.homeManagerConfiguration {
|
|
pkgs = nixpkgs.legacyPackages.x86_64-linux; # Home-manager requires 'pkgs' instance
|
|
extraSpecialArgs = { inherit inputs; }; # Pass flake inputs to our config
|
|
modules = (builtins.attrValues homeManagerModules) ++ [
|
|
# > Our main home-manager configuration file <
|
|
./home-manager/home.nix
|
|
# Our common nixpkgs config (unfree, overlays, etc)
|
|
(import ./nixpkgs-config.nix { inherit overlays; })
|
|
];
|
|
};
|
|
};
|
|
};
|
|
}
|